/*
 * Copyright 2015, Cyril Bur, IBM Corp.
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version
 * 2 of the License, or (at your option) any later version.
 */

#include "basic_asm.h"
#include "gpr_asm.h"
#include "fpu_asm.h"
#include "vmx_asm.h"
#include "vsx_asm.h"

/*
 * Large caveat here being that the caller cannot expect the
 * signal to always be sent! The hardware can (AND WILL!) abort
 * the transaction between the tbegin and the tsuspend (however
 * unlikely it seems or infrequently it actually happens).
 * You have been warned.
 */
/* long tm_signal_self(pid_t pid, long *gprs, double *fps, vector *vms, vector *vss); */
FUNC_START(tm_signal_self_context_load)
	PUSH_BASIC_STACK(512)
	/*
	 * Don't strictly need to save and restore as it depends on if
	 * we're going to use them, however this reduces messy logic
	 */
	PUSH_VMX(STACK_FRAME_LOCAL(5,0),r8)
	PUSH_FPU(512)
	PUSH_NVREGS_BELOW_FPU(512)
	std r3, STACK_FRAME_PARAM(0)(sp) /* pid */
	std r4, STACK_FRAME_PARAM(1)(sp) /* gps */
	std r5, STACK_FRAME_PARAM(2)(sp) /* fps */
	std r6, STACK_FRAME_PARAM(3)(sp) /* vms */
	std r7, STACK_FRAME_PARAM(4)(sp) /* vss */

	ld r3, STACK_FRAME_PARAM(1)(sp)
	cmpdi r3, 0
	beq skip_gpr_lc
	bl load_gpr
skip_gpr_lc:
	ld r3, STACK_FRAME_PARAM(2)(sp)
	cmpdi	r3, 0
	beq	skip_fpu_lc
	bl load_fpu
skip_fpu_lc:
	ld r3, STACK_FRAME_PARAM(3)(sp)
	cmpdi r3, 0
	beq	skip_vmx_lc
	bl load_vmx
skip_vmx_lc:
	ld r3, STACK_FRAME_PARAM(4)(sp)
	cmpdi	r3, 0
	beq	skip_vsx_lc
	bl load_vsx
skip_vsx_lc:
	/*
	 * Set r3 (return value) before tbegin. Use the pid as a known
	 * 'all good' return value, zero is used to indicate a non-doomed
	 * transaction.
	 */
	ld	r3, STACK_FRAME_PARAM(0)(sp)
	tbegin.
	beq	1f
	tsuspend. /* Can't enter a syscall transactionally */
	ld	r3, STACK_FRAME_PARAM(1)(sp)
	cmpdi	r3, 0
	beq skip_gpr_lt
	/* Get the second half of the array */
	addi	r3, r3, 8 * 18
	bl load_gpr
skip_gpr_lt:
	ld r3, STACK_FRAME_PARAM(2)(sp)
	cmpdi	r3, 0
	beq	skip_fpu_lt
	/* Get the second half of the array */
	addi	r3, r3, 8 * 18
	bl load_fpu
skip_fpu_lt:
	ld r3, STACK_FRAME_PARAM(3)(sp)
	cmpdi r3, 0
	beq	skip_vmx_lt
	/* Get the second half of the array */
	addi	r3, r3, 16 * 12
	bl load_vmx
skip_vmx_lt:
	ld r3, STACK_FRAME_PARAM(4)(sp)
	cmpdi	r3, 0
	beq	skip_vsx_lt
	/* Get the second half of the array */
	addi	r3, r3, 16 * 12
	bl load_vsx
skip_vsx_lt:
	li	r0, 37 /* sys_kill */
	ld r3, STACK_FRAME_PARAM(0)(sp) /* pid */
	li r4, 10 /* SIGUSR1 */
	sc /* Taking the signal will doom the transaction */
	tabort. 0
	tresume. /* Be super sure we abort */
	/*
	 * This will cause us to resume doomed transaction and cause
	 * hardware to cleanup, we'll end up at 1: anything between
	 * tresume. and 1: shouldn't ever run.
	 */
	li r3, 0
	1:
	POP_VMX(STACK_FRAME_LOCAL(5,0),r4)
	POP_FPU(512)
	POP_NVREGS_BELOW_FPU(512)
	POP_BASIC_STACK(512)
	blr
FUNC_END(tm_signal_self_context_load)
='2017-02-08 15:25:18 -0500'>2017-02-08</span></td><td><a href='/cgit.cgi/linux/net-next.git/commit/net?id=982acb97560c8118c2109504a22b0d78a580547d'>ipv4: fib: Notify about nexthop status changes</a></td><td>Ido Schimmel</td><td>1</td><td><span class='deletions'>-0</span>/<span class='insertions'>+33</span></td></tr>
<tr><td><span title='2017-02-08 14:39:19 -0500'>2017-02-08</span></td><td><a href='/cgit.cgi/linux/net-next.git/commit/net?id=8ef9594764617e3fd4500205b080b53c45c14c4b'>bridge: vlan tunnel id info range fill size calc cleanups</a></td><td>Roopa Prabhu</td><td>1</td><td><span class='deletions'>-18</span>/<span class='insertions'>+16</span></td></tr>
<tr><td><span title='2017-02-08 14:38:18 -0500'>2017-02-08</span></td><td><a href='/cgit.cgi/linux/net-next.git/commit/net?id=97e219b7c1f75b14b29abe28ad53e8709e8d15e5'>gro_cells: move to net/core/gro_cells.c</a></td><td>Eric Dumazet</td><td>6</td><td><span class='deletions'>-0</span>/<span class='insertions'>+100</span></td></tr>
<tr><td><span title='2017-02-07 16:29:30 -0500'>2017-02-07</span></td><td><a href='/cgit.cgi/linux/net-next.git/commit/net?id=3efa70d78f218e4c9276b0bac0545e5184c1c47b'>Merge git://git.kernel.org/pub/scm/linux/kernel/git/davem/net</a></td><td>David S. Miller